﻿* I9RESCUE.TXT
PROGRAM=NOT
CONTROL=PROGRAM,ERROR,SQL_DBO
BEGIN
=SET{_TITLE='RESUCUE 1/3'}; 
FORM1=       RESUCUE 1/3 
=J:
=SET{W0CNT=0,WSYSTEM=,WSEP=};
=DIR_DIR{?_OS_DRIVE??_P?I?_P?FILE};
=B:DIR_DIR_NEXT{W_DIR}EXIT{};
=SET{W0LEN=W_DIR@LENGTH};COMPUTE{W0LEN-=1};
=MESSAGE{W_DIR[W0LEN]};
=IF{W_DIR[W0LEN]!='.I'}BACK{B};
=COMPUTE{W0CNT+=1,W0LEN-=1};
=SET{WSYSTEM+=WSEP+W_DIR[1;W0LEN],WSEP=','};  　　
=BACK{B};
FORM1= SYSTEM= @@@@@@@@ 
DATA=SYSTEMX{8,1,}
CHECK1=?WSYSTEM? 
=SET{_SYSTEM=SYSTEMX,W0SYSTEM_LENGTH=SYSTEMX@LENGTH};
=COMPUTE{W0DB_LENGTH=W0SYSTEM_LENGTH+3};
=READ1_OPEN{?_OS_DRIVE??_P?I?_P?FILE?_P??_SYSTEM?.I?_P?BIN?_P??_SERVER_NAME?_?_SYSTEM?.CFG}{/};
=READ1_NEXT{DRIVE1,DRIVE2,DRIVE3,DRIVE4,DRIVE5,DRIVE6,OS_LOGIN,SECRET,GUEST};
=READ1_CLOSE{};
=J2:READ1_OPEN{?_OS_DRIVE??_P?I?_P?FILE?_P??_SYSTEM?.I?_P?BIN?_P??_SERVER?_?_SYSTEM?.I}{/};
=READ1_NEXT{LANG_SYSTEM,SERVER,SYSTEM,DB_SOFT,SETUP,INSTANCE,SYSTEM_NAME,W_PASSWORD_REAL
=,W_PASSWORD_TEST,W_PASSWORD_LINK};READ1_CLOSE{};
=J2:
=SET{_DB_SOFT=DB_SOFT,_SETUP=SETUP,_INSTANCE=INSTANCE};
=SET{LOGIN_ID=_LOGIN_ID_ADMIN};
*=IF{_DB='I'}EXIT2{PASSWORD_ADMIN};
FORM1=        REAL= @ 
FORM1=    REAL_LOG= @
FORM1= REAL_BACKUP= @
FORM1=        TEST= @
FORM1=    TEST_LOG= @
FORM1= TEST_BACKUP= @
REPEAT=6
DATA={O}DRIVE##{1}
REPEAT=
FORM1= OS_LOGIN= @@@ SECRET= @@@ GUEST= @@@
DATA={O}OS_LOGIN{3}
DATA={O}SECRET{3}
DATA={O}GUEST{3}
FORM1= LANG_SYSTEM= @@
FORM1=      SERVER= @@@@@@@@@@@@@@@
FORM1=      SYSTEM= @@@@@@@@
FORM1=     DB_SOFT= @@@@@@@@
FORM1=     SETUP= @
FORM1=    INSTANCE= @@@@@@@@@@@@@@@@
FORM1= SYSTEM_NAME= @
DATA={O}LANG_SYSTEM{2}
DATA={O}SERVER{15}
DATA={O}SYSTEM{8}
DATA={O}DB_SOFT{8}
DATA={O}SETUP{50}
DATA={O}INSTANCE{16}
DATA={O}SYSTEM_NAME{30}
FORM1=      ADMIN LOGIN-ID @@@@@@@@@@@@@@
DATA=LOGIN_ID{14,?$WPL?,!}ログインID
*=IF_NOT{_DB='H'}SET{_UPPER=LOGIN_ID,LOGIN_ID=_UPPER};
*=IF{_DB='P'}    SET{_LOWER=LOGIN_ID,LOGIN_ID=_LOWER};
=SET{_LOGIN_ID=LOGIN_ID};
=IF{_DB!='I'}JUMP{JX};
=SET{_UPPER=_USER};IF{_UPPER!=LOGIN_ID}ERROR{USER NOT '?LOGIN_ID?'('?_UPPER?')};
=JX:
FORM1=      ADMIN PASSWORD 
FORM1=@
DATA=PASSWORD_ADMIN{80,,!,*}管理者パスワード
=SET{WSW=0};
=SET{_LOGIN_PASSWORD=PASSWORD_ADMIN};
*=IF{_DB='I'}JUMP{I};
*=IF{_DB='P'}EXIT{};
=SET{W_SKIP_SW=0};
*=LOGIN_SQL{SELECT ?_NOW0? ?_FROM_DUAL?}IF{_DB_ERROR='P_NOT_EXIST'}SET{W_SKIP_SW=1};
=IF_NOT{_DB='H'}LOGIN_SQL{SELECT ?_NOW0? ?_FROM_DUAL?};
=IF    {_DB='H'}LOGIN_SQL{SELECT * FROM MASTER.SQL_USERS};
=EXIT{};
=I:SET{_UPPER=_USER};IF{_UPPER!='DB2ADMIN'}ERROR{USER NOT 'DB2ADMIN'('?_USER?')};
PROGRAM=NOT
CONTROL=PROGRAM,ERROR,SQL_DBO
BEGIN
=SET{_TITLE='RESUCUE 2/3'}; 
FORM1=       RESUCUE 2/3
FORM1= SYSTEM= @@@@@@@@ 
DATA={O}$SYSTEMX{8,1,}
M+JA+FORM1=  1---データベースが壊れたので復元をします。
M+JA+FORM1=　　　◎本番マスタはログをバックアップし、壊れた直前まで復元出来ます。
M+JA+FORM1=　　　　ログ自身が壊れていない事が前提です。　
M+JA+FORM1=　　　　ログ自身も壊れている場合は前回バックアップ時点の状態に復元します。　
M+JA+FORM1=　　　◎本番マスタ以外は前回バックアップ時点の状態に復元します。　
*M+JA+FORM1=  5---RDBMSを再インストールしました。
*M+JA+FORM1=  　　◎何らかの理由でRDBMSを再インストールした場合使用します。
*M+JA+FORM1=  　　◎I言語用データベースファイル群がありRDBMSに再設定します。
JA+FORM1=  9---システムを全部消します。
JA+FORM1=  　　◎システムを使用しなくなった場合使用します。
JA+FORM1=  　　　データベースは全部消えます。
JA+FORM1= NO= @  
*M+DATA=NO{1,1,9}{1,5,9}
*M-DATA=NO{1,1,9}{9}
DATA=NO{1,1,9}{1,9}
=SET{%ZZ_1='-',%ZZ_5='-',%ZZ_9='-',%ZZ_?NO?='+'};
=SET{WO='O'};IF{NO=5}SET{WO=};
PROGRAM=NOT
CONTROL=PROGRAM,ERROR,SQL_DBO
BEGIN
=SET{W_1='REAL_MAST',W_2='REAL_WORK',W_3='TEST_MAST',W_4='TEST_WORK'};
=         SET{_TITLE='システムを全部消します'};
=IF{$NO=1}SET{_TITLE='データベースが壊れたので復元を実施します'};
=IF{$NO=5}SET{_TITLE='データベースが壊れていないがRDBMSを再インストールします'};
=J:
FORM1=       RESUCUE 3/3
FORM1= SYSTEM= @@@@@@@@ 
DATA={O}$SYSTEMX{8,1,}
%ZZ_1+FORM1=*****( データベースが壊れたので復元を実施します )*****
%ZZ_5+FORM1=*****( データベースが壊れていないがRDBMSを再インストールします )*****
%ZZ_9+FORM1=*****( システムを全部消します )*****
*FORM1=       ★注意：パスワードはインストール時と同じものを入れてください。
*FORM1=       LINK PASSWORD @@@@@@@@@@@@@@ @@@@@@@@@@@@@@
*DATA={?$WO?}PASSWORD_LINK{14,1,H,*}LINK PASSWORD 1/1
*NAME=PASSWORD_CHECK
*=SET{W0=1,W_QU=''''};
*=PASSWORD_CHECK_B:
*=IF{W0>_DATA@LENGTH}JUMP{PASSWORD_CHECK_J};
*=IF{''''==_DATA[W0;1]}ERROR{?W_QU? FOUND};
*=COMPUTE{W0+=1};BACK{PASSWORD_CHECK_B};
*=PASSWORD_CHECK_J:
*NAME=
*DATA={?$WO?}PASSWORD_LINK2{14,1,H,*}LINK PASSWORD 2/2
*=IF{_DATA!=PASSWORD_LINK}ERROR{NOT EQUAL};
*FORM1=       TEST PASSWORD @@@@@@@@@@@@@@ @@@@@@@@@@@@@@
*DATA={?$WO?}PASSWORD_TEST{14,1,H,*}TEST PASSWORD 1/2
*COPY=PASSWORD_CHECK
*DATA={?$WO?}PASSWORD_TEST2{14,1,H,*}TEST PASSWORD 2/2
*FORM1=       REAL PASSWORD @@@@@@@@@@@@@@ @@@@@@@@@@@@@@
*DATA={?$WO?}PASSWORD_REAL{14,1,H,*}REAL PASSWORD 1/2
*COPY=PASSWORD_CHECK
*DATA={?$WO?}PASSWORD_REAL2{14,1,H,*}REAL PASSWORD 2/2
*=IF{_DATA!=PASSWORD_REAL}ERROR{NOT EQUAL};
FORM1=               RUN @@@@ {YES,QUIT}
DATA=YES{,1}{YES,QUIT}
=IF{_DATA='QUIT'}EXIT{};
P+=SET{_LOWER=_system,WLSYSTEM=_LOWER};
%ZZ_1-COMMENT_BEGIN
REPEAT=2
=SET{W_PATH_DAT##_OK=};
=SET{W_PATH_DAT##=};
=SET{W_PATH_LOG##_OK=};
=SET{W_PATH_LOG##=};
=SET{W_PATH_DAT##_BAK_OK=};
=SET{W_PATH_DAT##_BAK=};
=SET{W_PATH_LOG##_BAK_OK=};
=SET{W_PATH_LOG##_BAK=};
REPEAT=
*****( 1)*************************************************************************************************
***(　復元　 MSSQL ONLY )*********************************************************************************
**********************************************************************************************************
=SET{W_REAL1='REAL',W_REAL2='TEST'};
PROGRAM=NOT
FORM1= SYSTEM= @@@@@@@@ 
DATA={O}$SYSTEMX{8,1,}
=EXIT3{RUN};
FORM1= RUN= @ 
DATA=RUN{1} 
=READ1_OPEN{?_OS_DRIVE??_P?I?_P?FILE?_P??_SYSTEM?.I?_P?BIN?_P??_SERVER?_?_SYSTEM?.CFG}{/}ERROR{};
=READ1_NEXT{W_DRV_DAT1,W_DRV_LOG1,W_DRV_BAK1,W_DRV_DAT2,W_DRV_LOG2,W_DRV_BAK2}READ1_CLOSE{}ERROR{CFG FILE DATA NOT FOUND};
=READ1_CLOSE{};
REPEAT=2
=SET{W_PATH_DAT##='?W_DRV_DAT##?:?_P?I?_P?DATABASE?_P??_SYSTEM?.I'};
=SET{W_PATH_LOG##='?W_DRV_LOG##?:?_P?I?_P?DATABASE?_P??_SYSTEM?.I'};
=SET{W_PATH_DAT##_BAK='?W_DRV_BAK##?:?_P?I?_P?FILE?_P??_SYSTEM?.I?_P?DB_BACKUP_DAT'};
=SET{W_PATH_LOG##_BAK='?W_DRV_BAK##?:?_P?I?_P?DB_BACKUP_LOG?_P??_SYSTEM?.I'};
REPEAT=
=SET{W0C=0};SET{W_PATH_LOG=W_PATH_LOG1};
=LOOP:
=DIR{?W_PATH_LOG?}ERROR{};
=B:DIR_NEXT{W_FILE}JUMP{J};
=SET{W0L=W_FILE@COUNT};COMPUTE{W0L-=8,W0C+=1,W0DAT=W0L-13};
=SET{W_DB?W0C?=W_FILE[1;W0L]};
=                          SET{W_PATH_DAT=W_PATH_DAT2,W_PATH_DAT_BAK=W_PATH_DAT2_BAK};
=IF{W_FILE[W0DAT;4]='REAL'}SET{W_PATH_DAT=W_PATH_DAT1,W_PATH_DAT_BAK=W_PATH_DAT1_BAK};
*(データベース使用中はIF_FILEでは確認できず）
*=SET{W_DAT?W0C?='NG'};
*=IF_FILE{?W_PATH_DAT??_P??W_FILE[1;W0L]?_DAT.MDF}SET{W_DAT?W0C?='OK'};
=SET{W_BAK_DAT?W0C?='NG'};
=IF_FILE{?W_PATH_DAT_BAK??_P??W_FILE[1;W0L]?.DAT}SET{W_BAK_DAT?W0C?='OK'};
=BACK{B};
=J:
=IF{W_PATH_LOG=W_PATH_LOG2}JUMP{OK};
=SET{W_PATH_LOG=W_PATH_LOG2};BACK{LOOP};
=OK:
=SET{W_YES='YES'};
=SET{W_DAT_LOG1='DAT',W_BAK1=,W_BAK2='_BAK'};
REPEAT=2
REPEAT2=2
=SET{W_PATH_DAT##$$='W_PATH_DAT##?W_BAK$$?'};
=SET{W_PATH_LOG##$$='W_PATH_LOG##?W_BAK$$?'};
REPEAT=
REPEAT=2
REPEAT2=2
=SET{W_DIR=?W_PATH_DAT##$$?};
=DIR_DIR{?W_DIR?}JUMP{ERR};
=SET{?W_PATH_DAT##$$?_OK='OK',?W_PATH_DAT##$$?_OK@COLOR='W'};
=JUMP{OK};
=ERR:SET{?W_PATH_DAT##$$?_OK='NG',?W_PATH_DAT##$$?_OK@COLOR='R',W_YES='NO'};
=OK:
=SET{W_DIR=?W_PATH_LOG##$$?};
=DIR_DIR{?W_DIR?}JUMP{ERR};
=SET{?W_PATH_LOG##$$?_OK='OK',?W_PATH_LOG##$$?_OK@COLOR='W'};
=JUMP{OK};
=ERR:SET{?W_PATH_LOG##$$?_OK='NG',?W_PATH_LOG##$$?_OK@COLOR='R',W_YES='NO'};
=OK:
REPEAT=
NAME=PATH
REPEAT=2
FORM1=?$W_REAL##?_DAT     @@ @@
DATA={O}$W_PATH_DAT##_OK{2}
DATA={O}$W_PATH_DAT##{34}
FORM1=?$W_REAL##?_LOG     @@ @@
DATA={O}$W_PATH_LOG##_OK{2}
DATA={O}$W_PATH_LOG##{34}
FORM1=?$W_REAL##?_DAT_BAK @@ @@
DATA={O}$W_PATH_DAT##_BAK_OK{2}
DATA={O}$W_PATH_DAT##_BAK{34}
FORM1=?$W_REAL##?_LOG_BAK @@ @@
DATA={O}$W_PATH_LOG##_BAK_OK{2}
DATA={O}$W_PATH_LOG##_BAK{34}
REPEAT=
NAME=
FORM1= @@@@ {YES,NO}
DATA=YES{4}{?W_YES?}
PROGRAM=NOT
BEGIN
REPEAT=$W0C
=LOGIN_SQL{BACKUP LOG ?$W_DB##? TO ?$W_DB##?_LOG WITH INIT,NO_TRUNCATE}JUMP{ERR};
=SET{BAK_LOG##='OK',W_RUN##='ALL,NO'};
=JUMP{NEXT};
=ERR:SET{MSGB##=_ERROR}NOP{};SET{MSGA##=_DB_ERROR}NOP{};
=SET{BAK_LOG##='NG',W_RUN##='DAT,NO'};
=IF{MSGA##='M4214',='M4208'}SET{BAK_LOG##='SKIP'};
=NEXT:
=IF{BAK_LOG##='NG'}SET{BAK_LOG##@COLOR='R'};
=IF{W_BAK_DAT##='NG'}SET{W_BAK_DAT##@COLOR='R',W_RUN##='NO'};
*=IF{W_DAT##='NG'}SET{W_DAT##@COLOR='Y'};
REPEAT=
COPY=PATH
FORM1=************      BAK  BAK   
FORM1=** LOG   DAT RUN  LOG  DAT DB
REPEAT=$W0C
FORM1=@@ @@@@  @@  @@@@ @@@@ @@  ?$W_DB##? @@@@@@ @
DATA={O}GO##{2}
DATA={O}GO_LOG##{4}
DATA={O}GO_DAT##{2}
DATA=RUN##{4}{?W_RUN##?}
DATA={O}BAK_LOG##{4}
DATA={O}$W_BAK_DAT##{2}
**DATA={O}$W_DAT##{2}
DATA={O}MSGA##{6}
DATA={O}MSGB##{80} 
REPEAT=
FORM1=@@@@ {RUN}
DATA=RUN{3}{RUN,}
REPEAT=$W0C
=IF{RUN##='NO'}JUMP{NEXT};
=SET{W_NORECOVERY=};IF{RUN##='ALL'}SET{W_NORECOVERY='WITH NORECOVERY'};
=LOGIN_SQL{RESTORE DATABASE ?$W_DB##? FROM ?$W_DB##?_DAT ?W_NORECOVERY?}JUMP{ERR_DAT};
=SET{GO_DAT##='OK'  ,GO_DAT##@COLOR='W'};
=IF{RUN##='ALL'}JUMP{LOG};
=SET{GO_LOG##='SKIP',GO_LOG##@COLOR='W'};
=JUMP{OK};
=LOG:LOGIN_SQL{RESTORE LOG ?$W_DB##? FROM ?$W_DB##?_LOG}JUMP{ERR_LOG};
=SET{GO_LOG##='OK',GO_LOG##@COLOR='W'};
=OK:SET{GO##='OK',GO##@COLOR='B'};
=JUMP{NEXT};
=ERR_DAT:SET{MSGB##=_ERROR}NOP{};SET{MSGA##=_DB_ERROR}NOP{};    
=SET{GO_DAT##='NG',GO_DAT##@COLOR='R',GO_LOG##=,GO_LOG##@COLOR='W'};
=JUMP{NG};
=ERR_LOG:SET{MSGB##=_ERROR}NOP{};SET{MSGA##=_DB_ERROR}NOP{};    
=SET{GO_LOG##='NG',GO_LOG##@COLOR='R'};
=NG:SET{GO##='NG',GO##@COLOR='R'};
=NEXT:
REPEAT=
FORM1=END @ {YES}
DATA=END{4}{YES,}
=IF{_DATA='YES'}EXIT{1};
=EXIT{END};
%ZZ_1-COMMENT_END
**********************************************************************************************************
***(　再設定　)********************************************************************************************
%ZZ_5-COMMENT_BEGIN

%ZZ_5-COMMENT_END
***(　削除　)*************************************************************************
%ZZ_9-COMMENT_BEGIN
L+=LOGIN_SQL1{select distinct db from mysql.db where upper(left(db,?$W0DB_LENGTH?))='I_?_SYSTEM?_'};
M+=LOGIN_SQL1{select name from master.sys.databases where ?_SUBSTR?(name?_FROM?1?_FOR??$W0DB_LENGTH?)='I_?_SYSTEM?_'};
M+|L+=B:LOGIN_SQL1_NEXT{W_DB}JUMP{J};
M+|L+=LOGIN_SQL{DROP DATABASE ?W_DB?}SET{ERROR=_ERROR}NOP{};
M+=LOGIN_SQL{EXEC SP_DROPDEVICE '?W_DB?_DAT','DELFILE'}SET{ERROR=_ERROR}NOP{};
M+=LOGIN_SQL{EXEC SP_DROPDEVICE '?W_DB?_LOG','DELFILE'}SET{ERROR=_ERROR}NOP{};
M+|L+=BACK{B};
M+|L+=J:
L+=LOGIN_SQL1{select distinct user from mysql.user where (left(user,?$W0DB_LENGTH?))='I_?_SYSTEM?_'};
H+=LOGIN_SQL1{SELECT USER_ID FROM MASTER.SQL_USERS  where ?_SUBSTR?(USER_ID?_FROM?1?_FOR??$W0DB_LENGTH?-2)='I?_SYSTEM?'};
L+|H+=B:LOGIN_SQL1_NEXT{W_USER}JUMP{J};
L+=LOGIN_SQL{DROP USER ?W_USER?}SET{ERROR=_ERROR}NOP{};
H+=LOGIN_SQL{DROP SCHEMA AUTHORIZATION ?W_USER?}NOP{};
H+=LOGIN_SQL{REVOKE DBA     FROM ?W_USER?}NOP{};
H+=LOGIN_SQL{REVOKE CONNECT FROM ?W_USER?}NOP{};
L+|H+=BACK{B};
L+|H+=J:
L+=LOGIN_SQL1{select distinct db,table_name,user,host from mysql.tables_priv
L+= where upper(left(db,?$W0DB_LENGTH?))='I_?_SYSTEM?_'};
L+=B:LOGIN_SQL1_NEXT{W_DB,W_NAME,W_USER,W_HOST}JUMP{J};
L+=LOGIN_SQL{REVOKE ALL ON ?W_DB?.?W_NAME? FROM '?W_USER?'@'?W_HOST?'}SET{ERROR=_ERROR}NOP{};
L+=BACK{B};
L+=J:
L+=LOGIN_SQL1{select distinct routine_type,db,routine_name,user,host from mysql.procs_priv
L+= where upper(left(db,?$W0DB_LENGTH?))='I_?_SYSTEM?_'};
L+=B:LOGIN_SQL1_NEXT{W_TYPE,W_DB,W_NAME,W_USER,W_HOST}JUMP{J};
L+=LOGIN_SQL{REVOKE ALL ON ?W_TYPE? ?W_DB?.?W_NAME? FROM '?W_USER?'@'?W_HOST?'}SET{ERROR=_ERROR}NOP{};
L+=BACK{B};
L+=J:
*O+=LOGIN_SQL1{SELECT OWNER,OBJECT_NAME,OBJECT_TYPE FROM ALL_OBJECTS
*O+=WHERE OWNER LIKE 'I_?_SYSTEM?_%' AND OBJECT_TYPE IN('TABLE','VIEW','FUNCTION','PROCEDURE','TRIGGER')
*O+=AND OBJECT_NAME NOT LIKE 'BIN$%'};
*O+=B:SQL1_NEXT{W_OWNER,W_OBJECT,W_KIND}JUMP{J};
*O+=LOGIN_SQL{DROP ?W_KIND? ?W_OWNER?.?W_OBJECT?}IF{_DB_ERROR!='O942'}ERROR{?_DB_ERROR? ?_ERROR?};
*O+=BACK{B};
*O+=J:
*O+=SET{W_PER1='ZZZZ',W_PER2='ZZZY'};
*O+REPEAT=4
*O+REPEAT2=2
*O+=LOGIN_SQL{DROP TABLESPACE I_?_SYSTEM?_?W_##?_?W_PER$$? INCLUDING CONTENTS}IF{_DB_ERROR!='O959'}ERROR{?_DB_ERROR? ?_ERROR?};
*O+REPEAT=
*O+=SET{W_DRIVE1=$DRIVE1,W_DRIVE2=$DRIVE1,W_DRIVE3=$DRIVE4,W_DRIVE3=$DRIVE4};
*O+=COMMAND{
*O+REPEAT=4
*O+REPEAT2=2
*O+=ERASE ?W_DRIVE1?:\I\DATABASE\?_SYSTEM?.I\I_?_SYSTEM?_?W_##?_?W_PER$$?.ORA&
*O+REPEAT=
O+=SET{W_DRIVE1=$DRIVE1,W_DRIVE2=$DRIVE1,W_DRIVE3=$DRIVE4,W_DRIVE3=$DRIVE4};
O+=SET{W_COMMAND=,W_AND=};
O+=LOGIN_SQL1{SELECT TABLESPACE_NAME FROM USER_TABLESPACES WHERE ?_SUBSTR?(TABLESPACE_NAME?_FROM?1?_FOR??$W0DB_LENGTH?)='I_?_SYSTEM?_' ORDER BY 1};
O+=B:SQL1_NEXT{W_TABLESPACE_NAME}JUMP{J};
O+=LOGIN_SQL{DROP TABLESPACE ?W_TABLESPACE_NAME? INCLUDING CONTENTS}IF{_DB_ERROR!='O959'}ERROR{?_DB_ERROR? ?_ERROR?};
O+=SET{W_COMMAND+=W_AND+'ERASE ?W_DRIVE1?:\I\DATABASE\?_SYSTEM?.I\?W_TABLESPACE_NAME?.ORA',W_AND='&'};
O+=BACK{B};
O+=J:COMMAND{?W_COMMAND?
O+=?W_AND?ECHO ********************************************
O+=&ECHO ☆お願い☆：エラー確認後、Enterで続行下さい。
O+=&ECHO ********************************************
O+=&PAUSE};
=IF{_DB!='O'}JUMP{JX};
=SET{W_TABLE='ALL_USERS',W_USERNAME='USERNAME',W_EQUAL='I_?_SYSTEM?_',W_CASCADE='CASCADE'};
=JUMP{USER};
=JX:IF{_DB!='P',$W_SKIP_SW=1}JUMP{J};
=SET{W_TABLE='PG_USER',W_USERNAME='USENAME',W_EQUAL='i_?WLSYSTEM?_',W_CASCADE=};
=USER:LOGIN_SQL1{SELECT ?W_USERNAME? FROM  ?W_TABLE? WHERE ?_SUBSTR?(?W_USERNAME??_FROM?1?_FOR??$W0DB_LENGTH?)='?W_EQUAL?'};
=B:SQL1_NEXT{W_USER}JUMP{J};
=LOGIN_SQL{DROP USER ?W_USER? ?W_CASCADE?}NOP{};
=BACK{B};
=J:
*=SET{WUSER1='DBO_ZZ',WUSER2='INP_ZZ',WUSER3='OUT_ZZ',WUSER4='INP_AA',WUSER5='OUT_AA',WUSER6='LNK_ZZ',WUSER7='LNK_AA'};
*I+=WRITE1{'net user I_?_SYSTEM?_?WREAL_TEST?_?WUSER##? /delete'};
*I+=SET{WI=};
=SET{WREAL_TEST='REAL'};
NAME=DROP
M+=LOGIN_SQL1{select name from master.sys.syslogins where ?_SUBSTR?(name?_FROM?1?_FOR??$W0DB_LENGTH?)='I_?_SYSTEM?_'};
M+=B:LOGIN_SQL1_NEXT{W_LOGIN}JUMP{J};
M+=LOGIN_SQL{DROP LOGIN ?W_LOGIN?}SET{ERROR=_ERROR}NOP{};
M+=BACK{B};
M+=J:
*REPEAT=7
*I+=WRITE1{'net user I_?_SYSTEM?_?WREAL_TEST?_?WUSER##? /delete'};
*P+=LOGIN_SQL{DROP USER   i_?WLSYSTEM?_?WREAL_TEST?_?WUSER##?}
*P+= IF{_DB_ERROR!='P_NOT_EXIST'}ERROR{?_DB_ERROR? ?_ERROR?};
*REPEAT=
NAME=
=SET{WREAL_TEST='TEST'};
COPY=DROP
P+FORM1=           CONTINUE @@@@@
P+DATA=CONT{,}
W+P+=SET{W_P_PATH='?_DB_SOFT[2;1]?.?_DB_SOFT[3;1]?'};
W+D+=SET{W_P_PATH='?_DB_SOFT[2;1]?_?_DB_SOFT[3;1]?'};
W+P+=SET{INSTALL_PATH=_OS_DRIVE+_P+'Program Files'+_P+'PostgreSQL'+_P+W_P_PATH};
W+D+=SET{INSTALL_PATH=_OS_DRIVE+_P+'Program Files'+_P+'Firebird'+_P+'Firebird_'+W_P_PATH};
W+P+|D+=EXIT3{INSTALL_PATH}
W+P+|D+FORM1=INSTALL_PATH @
W+P+|D+DATA=INSTALL_PATH{65}
W+P+=SET{W_EXE=INSTALL_PATH+_P+'bin'+_P+'dropdb.exe'};
W+D+=SET{W_EXE=INSTALL_PATH+_P+'bin'+_P+'gsec.exe'};
W+P+|D+=IF_FILE_NOT{?W_EXE?}ERROR{?W_EXE? is not found};
W+D+=SET{W_DB=_INSTANCE+_P+'I'+_P+'DATABASE'+_P+_SYSTEM+'.I'+_P+'I_'+_SYSTEM+'.FDB'};
W+D+=WRITE1_OPEN{?_WORK?.TXT}{OT}{/};
W+D+=WRITE1{'DISPLAY'};
W+D+=WRITE1{'QUIT'};
W+D+=WRITE1_CLOSE{};
W+D+=COMMAND{"?W_EXE?" -user ?_LOGIN_ID? -password ?$PASSWORD_ADMIN? <?_PATH??_P??_WORK?.TXT >?_PATH??_P??_WORK?.TMP};
W+D+=READ1_OPEN{?_WORK?.TMP}{/};
W+D+=NEXT:READ1_NEXT{W_LOGIN}JUMP{END};
W+D+=SPLIT_CHAR{W_SPLIT}{?W_LOGIN?}{};
W+D+=IF_NOT{W_SPLIT1/'I_?_SYSTEM?_'}BACK{NEXT};
W+D+=COMMAND{"?W_EXE?" -user ?_LOGIN_ID? -password ?$PASSWORD_ADMIN? -delete ?W_SPLIT1?};
W+D+=BACK{NEXT};
W+D+=END:READ1_CLOSE{};
W+P+|D+=WRITE1_OPEN{?_TMP??_WORK?.BAT}{OT}{/};
W+P+|D+=WRITE1{'@ECHO OFF'};
W+P+|D+=WRITE1{'ECHO *****************************************************************************'};
W+P+|D+=WRITE1{'ECHO （注意：元の画面はデータベース使用中なので強制的に閉じました）'};
W+P+=WRITE1{'ECHO ★お願い★：パスワードを要求された場合はパスワードを入力して下さい。'};
W+P+|D+=WRITE1{'ECHO ★お願い★[Enter]キーを押して続行して下さい。'};
W+P+|D+=WRITE1{'ECHO *****************************************************************************'};
W+P+|D+=WRITE1{'PAUSE'};
W+D+=WRITE1{'ECHO ERASE  ?_INSTANCE??_P?I?_P?DATABASE?_P??_SYSTEM?.I?_P?I_?_SYSTEM?.FDB'};
W+D+=WRITE1{'     ERASE  ?_INSTANCE??_P?I?_P?DATABASE?_P??_SYSTEM?.I?_P?I_?_SYSTEM?.FDB'};
W+P+=WRITE1{'ECHO "?W_EXE?"  -U ?_LOGIN_ID? i_?WLSYSTEM?'};
W+P+=WRITE1{     '"?W_EXE?"  -U ?_LOGIN_ID? i_?WLSYSTEM?'};
W+P+|D+=WRITE1{'ECHO ********************************************'};
W+P+|D+=WRITE1{'ECHO ★お願い★：エラー確認後、Enterで終了です。'};
W+P+|D+=WRITE1{'ECHO ********************************************'};
W+P+|D+=WRITE1{'PAUSE'};WRITE1_CLOSE{};
W+P+|D+=EXE{\I\BIN\?_IV?ROOT?_OS??_FRAMEWORK?.EXE}{?_TMP??_WORK?.BAT};
*U+P+=COMMAND{echo su -c 'dropdb i_?WLSYSTEM?' postgres};
U+P+=COMMAND{su -c 'dropdb i_?WLSYSTEM?' postgres};
P+|D+=EXIT{0};
I+=WRITE1_OPEN{?_TMP??_WORK?.BAT}{OT}{/};
I+=WRITE1{'@ECHO ON'};
I+=WRITE1{'DB2CMD -I -C -W DB2 DROP DATABASE I_?_SYSTEM?'};
I+=COMMAND{NET USER >?_WORK?.TXT};
I+=SET{W0L=_SYSTEM@COUNT};COMPUTE{W0L+=3};
I+=READ1_OPEN{?_WORK?.TXT}{/};
I+=READ:READ1_NEXT{W_READ}JUMP{J2};
I+=SPLIT_CHAR{W_USER}{?W_READ?}{};
I+=SET{W0C=1};
I+=B0:IF{W0C>_SPLIT_COUNT}BACK{READ};
I+=SET{W_USER=W_USER?W0C?};
I+=IF{W_USER[1;W0L]!='I_?_SYSTEM?_'}JUMP{SKIP};
I+=WRITE1{'NET USER ?W_USER? /DELETE'};
I+=SKIP:COMPUTE{W0C+=1};BACK{B0}; 
I+=J2:READ1_CLOSE{}; 
I+=WRITE1{'@ECHO OFF'};
I+=WRITE1{'ECHO ********************************************'};
I+=WRITE1{'ECHO ☆お願い☆：エラー確認後、Enterで終了です。'};
I+=WRITE1{'ECHO ********************************************'};
I+=WRITE1{'PAUSE'};WRITE1_CLOSE{};
I+=EXE_WAIT{\I\BIN\?_IV?ROOT?_OS??_FRAMEWORK?.EXE}{?_TMP??_WORK?.BAT};
I+=ERASE_FILE{?_WORK?.BAT};
FORM1=             END @@@@ {YES}
DATA=END{,1}{YES,}
=IF{_DATA='YES'}EXIT{-2};
=EXIT{END};
FORM1=@
DATA={O}ERROR{80}
%ZZ_9-COMMENT_END
